#!/bin/ksh
#
# analyze the logfile for hostname...
# RCW 11/19/94
#

tail -500 log.access | awk '
    {
        host=$8
        $8=lookup(host)
        print $0
        next
    }

    END {
	print "################################################################"
	print "## SUMMARY                                                    ##"
	print "################################################################"
	for (address in COUNT) {
	    print COUNT[address], address, NAME[address] | "sort -n"
        }
    }

    function lookup(ipaddress) {
        if (NAME[ipaddress] == "") {
            cmd = sprintf("%s %s %s", \
                "nslookup -retry=1 -timeout=10", \
                ipaddress, "hplabs 2>/dev/null")

            while ( (cmd | getline x) == 1 ) {
                if (x ~ "^Name:") {
                    sub("^Name:[ ]*","",x)
                    NAME[ipaddress]=x
                }
            }
	    
	    close(cmd)
        }
        if (NAME[ipaddress] == "") {
            NAME[ipaddress]=ipaddress
        }
	COUNT[ipaddress]++
        return NAME[ipaddress]
    }

'